Diseño en Bloques Completos al Azar + Contrastes

En un experimento se evaluó la aplicación de productos químicos para el control de nematodos. Fueron utilizados los siguientes tratamientos:

A. Testigo absoluto (sin aplicación).

B. Oxamyl 1.5 lt (forma de aplicación: foliar)

C. Oxamyl 1.5 lt (forma de aplicación: al suelo)

D. Oxamyl 2.0 lt (forma de aplicación: foliar)

E. Carbofuran 15 gr. (aplicado al suelo)

F. Oxamyl 2.0 lt (forma de aplicación: al suelo)

Los tratamientos fueron analizados en un diseño bloques al azar con cinco repeticiones. La

variable de respuesta medida fue el número de nematodos vivos por unidad experimental.

Nematicidas	Bloque
	I	II	III	IV	V
A	307	371	379	360	339
B	187	192	320	243	296
C	277	328	363	195	344
D	115	235	248	267	256
E	173	267	251	254	200
F	195	131	171	253	253

Contrastes:

Definir con anterioridad un conjunto de (t−1) contrastes ortogonales. En este caso, como se tienen

6 tratamientos, los grados de libertad para los tratamientos es de 5, por lo tanto se pueden generar 5

subgrupos, los cuales se describen a seguir:

1. Testigo (A) contra Nematicidas (B, C, D, E, F)

2. Carbofuran (E) contra Oxamyl (B,C,D,F)

3. Oxamyl aplicado al follaje (1.5 y 2.0 lts) contra Oxamyl aplicado al suelo (1.5 y 2.0 lts)

4. Oxamyl 1.5 lt (aplicado al follaje) contra Oxamyl 2.0 lt (aplicado al suelo)

5. Oxamyl 1.5 lt (aplicado al suelo) contra Oxamyl 2.0 lt (aplicado al suelo)

Los coeficientes de los contrastes (Ci) son:

Contrastes		Tratamientos						Suma
		A	B	C	D	E	F
C1	A = B+C+D+E+F	-5	1	1	1	1	1	0
C2	E = B+C+D+F	0	1	1	1	-4	1	0
C3	B + D = C + F	0	-1	1	-1	0	1	0
C4	B = D	0	-1	0	1	0	0	0
C5	C = F	0	0	-1	0	0	1	0

Download code / Descarga de código:

http://adf.ly/YIDx5

Procedimiento en SAS:

Title1 'Diseño en Bloques Completos al Azar + Contrastes';

Title2 'Prueba de 5 nematicidas';

DATA nematodos;

INPUT Nematicidas $ Bloques NVPU; /* El simbolo $ despues de una

variable indica que es de caracter alphanumerico*/

datalines;

A 1 307

A 2 371

A 3 379

A 4 360

A 5 339

B 1 187

B 2 192

B 3 320

B 4 243

B 5 296

C 1 277

C 2 328

C 3 363

C 4 195

C 5 344

D 1 115

D 2 235

D 3 248

D 4 267

D 5 256

E 1 173

E 2 267

E 3 251

E 4 254

E 5 200

F 1 195

F 2 131

F 3 171

F 4 253

F 5 253

;

proc glm data=nematodos;

class Nematicidas Bloques;/*Variables clasificatorias*/

model NVPU=Nematicidas Bloques / ss3;/*modelo / suma de cuadrados TIPO3*/

/*

Contrastes programados:

1. Testigo (A) contra Nematicidas (B, C, D, E, F)

2. Carbofuran (E) contra Oxamyl (B,C,D,F)

3. Oxamyl aplicado al follaje (1.5 y 2.0 lts) contra Oxamyl aplicado al suelo (1.5 y 2.0 lts)

4. Oxamyl 1.5 lt (aplicado al follaje) contra Oxamyl 2.0 lt (aplicado al suelo)

5. Oxamyl 1.5 lt (aplicado al suelo) contra Oxamyl 2.0 lt (aplicado al suelo)

*/

/*---------------------------------------- A  B  C  D  E  F -----*/

 contrast "A = B+C+D+E+F"    Nematicidas  -5  1  1  1  1  1; 

 contrast "E = B+C+D+F "     Nematicidas   0  1  1  1 -4  1; 

 contrast "B+D = C+F"        Nematicidas   0 -1 1 -1  0  1;

 contrast "B = D"            Nematicidas   0 -1  0  1  0  0;

 contrast "C = F"            Nematicidas   0  0 -1  0  0  1;

run;

quit;

Download code / Descarga de código:

http://adf.ly/YIDx5