Diseño Completamente al Azar con Submuestras

En un experimento de campo, el investigador puede no tener tiempo para cosechar (totalmente) cada unidad experimental. De esta manera, podrá seleccionar al azar varios cuadros por parcela y cosechar el grano en cada cuadro seleccionado. Describiríamos estas observaciones como “muestras dentro de unidades experimentales”.

Tratamientos	Submuestra	Repeticiones
		I	II	III	IV
A	1	5.6	5	5.5	5.3
	2	5.7	5.1	5.4	5.5
B	1	6.7	4.7	5.7	6.2
	2	8.7	3.7	6.5	5.8
C	1	7.6	7.4	7.5	5.7
	2	7.8	7.2	7.6	6.7

t = 3 ( A, B, C)

r = 4 (I, II, III, IV)

m= 2 (submuestras)

Download code / Descarga de código:

http://adf.ly/YID9S

Procedimiento en SAS:

Title1 'Diseño Completamente al Azar con Submuestras';

Title2 'Tratamientos, Repeticiones, Submuestra, Produccion';

data produccion;

input Tratamientos $ Repeticiones Submuestra Produccion;/*El simbolo $ despues de 

una variable indica que es de caracter alphanumerico*/

datalines;

A 1 1 5.6

A 1 2 5.7

B 1 1 6.7

B 1 2 8.7

C 1 1 7.6

C 1 2 7.8

A 2 1 5.0

A 2 2 5.1

B 2 1 4.7

B 2 2 3.7

C 2 1 7.4

C 2 2 7.2

A 3 1 5.5

A 3 2 5.4

B 3 1 5.7

B 3 2 6.5

C 3 1 7.5

C 3 2 7.6

A 4 1 5.3

A 4 2 5.5

B 4 1 6.2

B 4 2 5.8

C 4 1 5.7

C 4 2 6.7

;

Proc sort data=produccion;

by tratamientos;

/*el procedimiento ordena los datos de acuerdo con lo que estipule el parametro

by, para este caso ordena los datos de A hacia C en la varable tratamiento*/

run;

proc glm data=produccion;

class Tratamientos Repeticiones; /*Variables clasificatorias*/

model Produccion= Tratamientos Tratamientos*Repeticiones / ss3;/*modelo / suma de cuadrados TIPO3*/

test h=Tratamientos e=Tratamientos*Repeticiones; /*con la instruccion test se realiza la prueba de

hipotesis 'h' a los tratamientos con el error 'e=Tratamientos*Repeticiones'*/

means Tratamientos / lsd lines e=Tratamientos*Repeticiones; /*lsd=comparacion entre los tratamientos,

lines=evita comparaciones 1 a 1 para lsd cuando hay datos faltantes; las cuales se presentan por 

omision, e=Tratamientos*Repeticiones en este caso le indica a lsd usar el CME deel error experimental*/

run;

quit;

Download code / Descarga de código:

http://adf.ly/YID9S

Diseño Completamente al Azar Desbalanceado (DCA)

Considere las siguientes producciones diarias (Kg) de leche (con 4% de grasa) de vacas para lactación, sometidas a la administración de raíces y tubérculos, como suplemento de invierno en la alimentación; datos de un experimento citado por Gomes, FP (2000).

Repetición	SIN	MANDIOCA	ARARUTA	BATATA DOCE
	SUPLEMENTO	(Manihot esculenta)	(Maranta arundinacea)	(Ipomoea batata)
1	19.58	23.4	35.43	22.15
2	21.07	22.37	32.47	24.37
3	23.43	24.36	34.48	26.54
4	25.42	25.12	33.79	20.37
5	22.81	22.94	35.04	19.54
6	23.52		35.19	24.06

Download code / Descarga de código:

http://adf.ly/YIAqG

Procedimiento en SAS:

Title1 'Diseño Completamente al Azar Desbalanceado';

Title2 'Influencia de 4 suplementos alimenticios en la produccion de leche';

data vacas;

input Alimentacion $ 15. Repeticion ProLeche;/* El simbolo $ despues de 

una variable indica que es de caracter alphanumerico, y el numero '15.'

son los espacios escritos hasta donde se leera la variable*/

datalines;

Sin_Suplemento 1 19.58

Sin_Suplemento 2 21.07

Sin_Suplemento 3 23.43

Sin_Suplemento 4 25.42

Sin_Suplemento 5 22.81

Sin_Suplemento 6 23.52

Mandioca    1 23.4

Mandioca    2 22.37

Mandioca    3 24.36

Mandioca    4 25.12

Mandioca    5 22.94

Araruta        1 35.43

Araruta        2 32.47

Araruta        3 34.48

Araruta        4 33.79

Araruta        5 35.04

Araruta        6 35.19

BatataDoce    1 22.15

BatataDoce    2 24.37

BatataDoce    3 26.54

BatataDoce    4 20.37

BatataDoce    5 19.54

BatataDoce    6 24.06

;

proc print;/*Se presenta los datos en su respectiva variable, es importante

confirmar la ubicacion de nuestos datos al usar variables alphanumericas con

una longitud mayor de 12 espacios*/

run;

ods html; /*solo para SAS 9.1.3 o superior, inicia Box-plot de medias*/

ods graphics on; /*solo para SAS 9.1.3 o superior*/

proc glm data=vacas;

class Alimentacion;/*Variables clasificatorias*/

model ProLeche=Alimentacion / ss3;/*modelo / suma de cuadrados TIPO3*/

ods html;/*solo para SAS 9.1.3 o superior*/

means Alimentacion / Tukey lines;/*Tukey=comparacion entre los tratamientos,

lines=evita comparaciones 1 a 1 para Tukey cuando hay datos faltantes que se

presentan por omision*/

means Alimentacion / dunnett('Sin_Suplemento');/*Dunnett=comparacion de los

tratamientos contra un testigo 'Sin_Suplemento'*/

run;

quit;

Download code / Descarga de código:

http://adf.ly/YIAqG

Diseño Completamente al Azar (DCA)

En un experimento de arroz se probaron cinco insecticidas para el control de la plaga Sogatodes orizicola, la variedad utilizado fue CICA 8; este experimento se lleva a nivel de campo, las parcelas experimentales fueron de dos metros cuadrados y los resultados obtenidos para las variables de respuesta fueron las siguientes:

Tratamientos	Repeticiones
	1	2	3	4
A	3.0	3.5	3.8	3.2
B	2.3	2.0	2.1	2.2
C	2.7	2.8	3.0	2.4
D	5.0	4.5	3.8	4.2
E	6.0	8.0	7.0	5.5

Download code / Descarga de código:

http://adf.ly/YIBzS

Procedimiento en SAS:

Title1 'Diseño Completamente al Azar';

Title2 'Prueba de 5 insecticidas en arroz';

DATA arroz;

INPUT Tratamiento $ Repeticion Produccion; /* El simbolo $ despues de 

una variable indica que es de caracter alphanumerico*/

datalines;

A 1 3.0

A 2 3.5

A 3 3.8

A 4 3.2

B 1 2.3

B 2 2.0

B 3 2.1

B 4 2.2

C 1 2.7

C 2 2.8

C 3 3.0

C 4 2.9

D 1 5.0

D 2 4.5

D 3 3.8

D 4 4.2

E 1 6.0

E 2 8.0

E 3 7.0

E 4 5.5

;

ods html; /*solo para SAS 9.1.3 o superior, inicia Box-plot de medias*/

ods graphics on; /*solo para SAS 9.1.3 o superior*/

proc glm data=arroz;

class Tratamiento;/*Variables clasificatorias*/

model Produccion=Tratamiento / ss3;/*modelo / suma de cuadrados TIPO3*/

ods html;/*solo para SAS 9.1.3 o superior*/

means Tratamiento / Tukey; /*Comparacion simultanea de los tratamientos*/

means Tratamiento / Tukey cldiff; /*Comparacion 1 a 1 de los tratamientos*/

run;

quit;

Download code / Descarga de código:

http://adf.ly/YIBzS