Experimento Factorial con Arreglo en Franjas Divididas

Los datos que se presentan a continuación se refieren al Pol% de la caña de azúcar, obtenido de un experimento en franjas en el ingenio Santa Cruz, citado por Nogueira (2000), que involucró 2 factores A y B; correspondientes a tipos de surcos, asociado con distanciamientos entre surcos y densidades de siembra, con 4 y 3 niveles respectivamente, siendo:

A1: surco simple y distanciamiento de 1.40 m.

A2: surco doble y distanciamiento de 1.40 m x 0.90 m.

A3: surco de base larga y distanciamiento de 1.70 m.

A4: surco de base larga y distanciamiento de 1.90 m.

B1: 4 toneladas de semilla/ha

B2: 6 toneladas de semilla/ha

B3: 8 toneladas de semilla/ha

Surcos	Densidades	Bloques
		I	II	III	IV
A1	B1	17.67	17.23	17.43	17.61
	B2	17.31	17.6	17.05	16.91
	B3	17.49	17.3	17.68	18.27
A2	B1	17.19	17.85	17.44	17.56
	B2	17.21	17.26	16.71	17.52
	B3	18.04	16.38	17.23	17.14
A3	B1	17.39	17.54	16.61	17.51
	B2	17.39	17.67	16.77	17.61
	B3	17.69	17.02	17.34	18.02
A4	B1	17.19	17.57	17.72	17.73
	B2	16.78	17.57	17.79	18.27
	B3	17.86	16.85	18.12	17.94

Download code / Descarga de código:

http://adf.ly/YIHgy

Procedimiento en SAS:

Title1 'Experimento Factorial con Arreglo en Franjas Divididas';
Title2 'Cuatro distancias de siembra y tres desnsidades de siembra para caña';
data franja;
input Bloque Surcos $ Densidades $ PolAzucar;/*El simbolo $ despues de
una variable indica que es de caracter alphanumerico*/
datalines;
1 A1 B1 17.67
1 A1 B2 17.31
1 A1 B3 17.49
1 A2 B1 17.19
1 A2 B2 17.21
1 A2 B3 18.04
1 A3 B1 17.39
1 A3 B2 17.39
1 A3 B3 17.69
1 A4 B1 17.19
1 A4 B2 16.78
1 A4 B3 17.86
2 A1 B1 17.23
2 A1 B2 17.6
2 A1 B3 17.3
2 A2 B1 17.85
2 A2 B2 17.26
2 A2 B3 16.38
2 A3 B1 17.54
2 A3 B2 17.67
2 A3 B3 17.02
2 A4 B1 17.57
2 A4 B2 17.57
2 A4 B3 16.85
3 A1 B1 17.43
3 A1 B2 17.05
3 A1 B3 17.68
3 A2 B1 17.44
3 A2 B2 16.71
3 A2 B3 17.23
3 A3 B1 16.61
3 A3 B2 16.77
3 A3 B3 17.34
3 A4 B1 17.72
3 A4 B2 17.79
3 A4 B3 18.12
4 A1 B1 17.61
4 A1 B2 16.91
4 A1 B3 18.27
4 A2 B1 17.56
4 A2 B2 17.52
4 A2 B3 17.14
4 A3 B1 17.51
4 A3 B2 17.61
4 A3 B3 18.02
4 A4 B1 17.73
4 A4 B2 18.27
4 A4 B3 17.94
;

proc glm data=franja;
class Bloque Surcos Densidades; /*Variables clasificatorias*/
model PolAzucar= Bloque Surcos Bloque*Surcos Densidades Bloque*Densidades Surcos*Densidades / ss3;/*modelo / suma de cuadrados TIPO3*/
test h=Bloque Surcos e=Bloque*Surcos; /*con la instruccion test se realiza la prueba de
hipotesis 'h' a los tratamientos con el error 'e=Bloque*Surcos' */
test h=Densidades e=Bloque*Densidades;
means Surcos / Tukey lines e=Bloque*Surcos; /*Tukey=comparacion entre los tratamientos,
lines=evita comparaciones 1 a 1 para Tukey cuando hay datos faltantes; las cuales se presentan por
omision, e=Bloque*Surcos en este caso le indica a Tukey que CME usar*/
lsmeans Densidades / pdiff=all adjust=Tukey e=Bloque*Densidades;/*Calcula promedios de efectos por el método de mínimos
cuadrados (medias ajustadas), es lo mas aconsejado para las interacciones*/
lsmeans Surcos*Densidades / pdiff=all adjust=Tukey;/*Calcula promedios de efectos por el método de mínimos
cuadrados (medias ajustadas), es lo mas aconsejado para las interacciones*/
run;
quit;

Download code / Descarga de código:

http://adf.ly/YIHgy

Experimento Factorial con Arreglo en Parcelas Divididas

En un experimento se probaron dos métodos de siembra y tres variedades de arroz. Por razones de facilidad en el manejo del mismo, se decidió utilizar un arreglo en parcelas divididas, en donde las parcelas grandes correspondieron a los métodos de siembra y en las parcelas pequeñas se sembraron las tres variedades de arroz.


Los tratamientos se distribuyeron mediante un diseño en bloques completos al azar con 4 repeticiones.
La variable de respuesta fué kg/parcela de 72 m2. A continuación se detallan los factores evaluados.


Métodos de siembra: S: Secano I: Inundación
Variedades: BB: Blue Bonnett BP: Belle Patna CR: Criolla


Rendimiento de arroz en kg/parcela de 72 m2 , al comparar distintos métodos de siembra en diferentes variedades de arroz.

Métodos de siembra	Variedades	Bloque
		I	II	III	IV
S	BB	8.5	8.2	8	7.6
	BP	8	7	7.3	6.9
	CR	10	10.8	11	11.6
I	BB	5.8	5.6	5.2	5.8
	BP	7	7.1	7.3	7.3
	CR	8.3	8	8	8.7

Download code / Descarga de código:

http://adf.ly/YIHJG

Procedimiento en SAS:



Title1 'Experimento Factorial con Arreglo en Parcelas Divididas';
Title2 'Dos sistemas de siembra con tres variedades de arroz';
data dividida;
input Bloque Siembra $ Variedad $ KgArroz;/*El simbolo $ despues de 
una variable indica que es de caracter alphanumerico*/
datalines;
1 S BB 8.5
1 S BP 8
1 S CR 10
1 I BB 5.8
1 I BP 7
1 I CR 8.3
2 S BB 8.2
2 S BP 7
2 S CR 10.8
2 I BB 5.6
2 I BP 7.1
2 I CR 8
3 S BB 8
3 S BP 7.3
3 S CR 11
3 I BB 5.2
3 I BP 7.3
3 I CR 8
4 S BB 7.6
4 S BP 6.9
4 S CR 11.6
4 I BB 5.8
4 I BP 7.3
4 I CR 8.7
;


proc glm data=dividida;
class Bloque Siembra Variedad; /*Variables clasificatorias*/
model KgArroz= Bloque Siembra Bloque*Siembra Variedad Siembra*Variedad / ss3;/*modelo / suma de cuadrados TIPO3*/
test h=Bloque Siembra e=Bloque*Siembra; /*con la instruccion test se realiza la prueba de
hipotesis 'h' a los tratamientos con el error 'e=Bloque*Siembra'*/
means siembra / Tukey lines e=Bloque*Siembra; /*Tukey=comparacion entre los tratamientos,
lines=evita comparaciones 1 a 1 para Tukey cuando hay datos faltantes; las cuales se presentan por 
omision, e=Bloque*Siembra en este caso le indica a Tukey que CME usar*/
lsmeans Variedad / pdiff=all adjust=Tukey;/*Calcula promedios de efectos por el método de mínimos 
cuadrados (medias ajustadas), es lo mas aconsejado para las interacciones*/
lsmeans Siembra*Variedad / pdiff=all adjust=Tukey;/*Calcula promedios de efectos por el método de mínimos 
cuadrados (medias ajustadas), es lo mas aconsejado para las interacciones*/
run;
quit;

Download code / Descarga de código:

http://adf.ly/YIHJG

Experimento Factorial en Arreglo Combinatorio en BCA

Se estudió el efecto de diferentes dosis de fertilizante fosforado sobre dos tipos de planta de

haba Vicia faba. Se pensó que los tipos de planta bien podían responder en forma diferente a la fertilización, así que se decidió llevar a cabo un experimento factorial con dos factores:

Factor	Nivel
	1	2	3
A. Tipo de Planta	Corto	Alto
B. Dosis de Fósforo	0 Kg/ha P205	25 Kg/ha P205	50 Kg/ha P205

El experimento se llevó a cabo en un diseño en bloques completos al azar en arreglo combinatorio, con cuatro repeticiones. Los resultados (producción en kg/ha) se aprecian a continuación:

Tipo de Planta	Dosis de Fosforo	Bloques
		I	II	III	IV
Corto	0	11.5	13.6	14.3	14.5
	25	17.1	17.6	17.6	18.1
	50	18.2	17.6	18.2	18.9
Largo	0	11	11.2	12.1	12.6
	25	8.3	10.5	9.1	12.8
	50	15.7	16.7	16.6	17.5

Download code / Descarga de código:

http://adf.ly/YIH4n

Procedimiento en SAS:


Title1 'Experimento Factorial en Arreglo Combinatorio dispuesto en Bloques Completos al Azar';
Title2 'Tres dosis de fertilizante fosforado sobre dos tipos de planta de haba Vicia faba';
data haba;
input Bloque Planta $ Fosforo KgHaba;/*El simbolo $ despues de 
una variable indica que es de caracter alphanumerico*/
datalines;
1 Corto 0 11.5
1 Corto 25 17.1
1 Corto 50 18.2
1 Largo 0 11
1 Largo 25 8.3
1 Largo 50 15.7
2 Corto 0 13.6
2 Corto 25 17.6
2 Corto 50 17.6
2 Largo 0 11.2
2 Largo 25 10.5
2 Largo 50 16.7
3 Corto 0 14.3
3 Corto 25 17.6
3 Corto 50 18.2
3 Largo 0 12.1
3 Largo 25 9.1
3 Largo 50 16.6
4 Corto 0 14.5
4 Corto 25 18.1
4 Corto 50 18.9
4 Largo 0 12.6
4 Largo 25 12.8
4 Largo 50 17.5
;


proc glm data=haba;
class Bloque Planta Fosforo; /*Variables clasificatorias*/
model KgHaba= Bloque Planta Fosforo Planta*Fosforo / ss3;/*modelo / suma de cuadrados TIPO3*/
means Planta Fosforo / Tukey; /*Tukey=comparacion entre los tratamientos,
lines=evita comparaciones 1 a 1 para Tukey cuando hay datos faltantes; las cuales se presentan por omision*/
lsmeans Planta*Fosforo / pdiff=all adjust=Tukey;/*Calcula promedios de efectos por el método de mínimos 
cuadrados (medias ajustadas), es lo mas aconsejado para las interacciones*/
run;
quit;

Download code / Descarga de código:

http://adf.ly/YIH4n