Diseño de Cuadrado Latino con Submuestra

En un experimento con la variedad de tomate Imperial Rojo, se evaluaron cuatro

distanciamientos de siembra:

A. 0.6 metros      C. 1.0 metros

B. 0.8 metros      D. 1.2 metros

Determinando su efecto sobre el rendimiento de frutos (expresado en kilogramos por parcela neta).

Filas (i)	Columnas (j)
	1		2		3		4
1	A	15	B	18	D	15	C	14
		14		17		15		13
2	C	19	D	13	B	12	A	17
		15		13		16		16
3	D	12	A	16	C	18	B	16
		14		15		16		15
4	B	17	C	20	A	13	D	13
		13		16		15		12

Download code / Descarga de código:

http://adf.ly/YIFMP

Procedimiento en SAS:


Title1 'Diseño de Cuadrado Latino con Submuestra';
Title2 'Efecto de 4 distancias de siembra sobre el rendimiento en tomate';
DATA rendimiento;
INPUT Columna Fila Tratamiento $ Submuestra Rendimiento; /* El simbolo $ despues de una
variable indica que es de caracter alphanumerico*/
datalines;
1 1 A 1 15
1 1 A 2 14
1 2 C 1 19
1 2 C 2 15
1 3 D 1 12
1 3 D 2 14
1 4 B 1 17
1 4 B 2 13
2 1 B 1 18
2 1 B 2 17
2 2 D 1 13
2 2 D 2 13
2 3 A 1 16
2 3 A 2 15
2 4 C 1 20
2 4 C 2 16
3 1 D 1 15
3 1 D 2 15
3 2 B 1 12
3 2 B 2 16
3 3 C 1 18
3 3 C 2 16
3 4 A 1 13
3 4 A 2 15
4 1 C 1 14
4 1 C 2 13
4 2 A 1 17
4 2 A 2 16
4 3 B 1 16
4 3 B 2 15
4 4 D 1 13
4 4 D 2 12
;


proc glm data=rendimiento;
class Columna Fila Tratamiento;/*Variables clasificatorias*/
model Rendimiento= Columna Fila  Tratamiento Tratamiento*Columna*Fila / ss3;/*modelo / suma de cuadrados TIPO3*/
test h=Tratamiento e=Tratamiento*Columna*Fila; /*con la instruccion test se realiza la prueba de
hipotesis 'h' a los tratamientos con el error 'e=Tratamiento*Columna*Fila'*/
means Tratamiento / lsd lines e=Tratamiento*Columna*Fila; /*lsd=comparacion entre los tratamientos,
lines=evita comparaciones 1 a 1 para lsd cuando hay datos faltantes; las cuales se presentan por 
omision, e=Tratamiento*Columna*Fila en este caso le indica a lsd que CME usar*/
run;
quit;


proc glm data=rendimiento;
class Columna Fila Tratamiento;/*Variables clasificatorias*/
model Rendimiento= Columna Fila  Tratamiento;
means Tratamiento / lsd lines; /*lsd=comparacion entre los tratamientos,
lines=evita comparaciones 1 a 1 para lsd cuando hay datos faltantes; las cuales se presentan por 
omision*/;
run;
quit;

Download code / Descarga de código:

http://adf.ly/YIFMP