Diseño de Cuadrados Latinos Repetidos

Filas: 4 primeros días de la semana

Columnas: 4 tiendas en la ciudad.

Tratamientos: a: Manzana regular al precio menor, b: Manazana calidad mediana, c: Manzana uniforme,  d: manzana uniforme de color bonito. 

Variable de respuesta: peso en libras de 100 manzanas comprados por los clientes.

Download code / Descarga de código:

http://adf.ly/YIGDY

Procedimiento en SAS:



Title1 'Diseño de Cuadrados Latinos Repetidos';
data manzana;
input Semana Dia Tienda Tratamiento $ Peso;/* El simbolo $ despues de una
variable indica que es de caracter alphanumerico*/
datalines;
1 1 1 a 14
1 1 2 b 8
1 1 3 c 40
1 1 4 d 48
1 2 1 b 20
1 2 2 a 22
1 2 3 d 48
1 2 4 c 25
1 3 1 d 24
1 3 2 c 12
1 3 3 b 12
1 3 4 a 27
1 4 1 c 31
1 4 2 d 16
1 4 3 a 32
1 4 4 b 22
2 1 1 b 24
2 1 2 d 30
2 1 3 c 24
2 1 4 a 12
2 2 1 d 42
2 2 2 a 4
2 2 3 b 12
2 2 4 c 32
2 3 1 a 8
2 3 2 c 8
2 3 3 d 36
2 3 4 b 28
2 4 1 c 28
2 4 2 b 32
2 4 3 a 48
2 4 4 d 54
;


title2 "Analisis por separado de la Primera semana y la Segunda semana";
proc glm data=manzana;
class Dia Tienda Tratamiento;/*Variables clasificatorias*/
model Peso = Dia Tienda Tratamiento /ss3;/*modelo / suma de cuadrados TIPO3*/
means Tratamiento / Tukey lines;/*Tukey=comparacion entre los tratamientos,
lines=evita comparaciones 1 a 1 para Tukey cuando hay datos faltantes; las cuales se presentan por 
omision*/
by Semana;
run;


title2 "Analisis combinado de Primera y Segunda semanas";
proc glm data=manzana;
class Semana Dia Tienda Tratamiento;/*Variables clasificatorias*/
model Peso = Semana Dia(Semana) Tienda(Semana) Tratamiento Tratamiento*Semana/ ss3;
/*modelo / suma de cuadrados TIPO3*/
means Tratamiento / Tukey lines;/*Tukey=comparacion entre los tratamientos,
lines=evita comparaciones 1 a 1 para Tukey cuando hay datos faltantes; las cuales se presentan por 
omision*/
run;
quit;

Download code / Descarga de código:

http://adf.ly/YIGDY